extends "res://addons/gut/test.gd"

const NpcContent = preload("res://scripts/npc/npc_content.gd")

func _fenn() -> Dictionary:
	return {"id": "fenn", "capabilities": {
		"offerable_quests": ["find_the_ledger"],
		"giveable_items": [],
		"revealable_topics": ["varrell_twins", "fenns_debt"]}}


func test_universal_moves_always_present():
	var moves = NpcContent.available_moves(_fenn(), GameState.new(), CanonLog.new())
	for m in ["adjust_disposition", "refuse", "end_conversation", "become_hostile"]:
		assert_true(m in moves, "missing universal move %s" % m)


func test_offers_unstarted_quest_and_unrevealed_topics():
	var moves = NpcContent.available_moves(_fenn(), GameState.new(), CanonLog.new())
	assert_true("offer_quest(find_the_ledger)" in moves)
	assert_true("reveal(varrell_twins)" in moves)
	assert_true("reveal(fenns_debt)" in moves)


func test_active_quest_is_not_offered_again():
	var log = CanonLog.new()
	log.add_quest("find_the_ledger", "x", "y")
	var moves = NpcContent.available_moves(_fenn(), GameState.new(), log)
	assert_false("offer_quest(find_the_ledger)" in moves)


func test_revealed_topic_drops_out():
	var gs = GameState.new()
	gs.mark_revealed("varrell_twins")
	var moves = NpcContent.available_moves(_fenn(), gs, CanonLog.new())
	assert_false("reveal(varrell_twins)" in moves)
	assert_true("reveal(fenns_debt)" in moves)


func test_accept_item_offered_per_held_item():
	var gs = GameState.new()
	gs.add_item("worn_shortsword", 2)
	var moves = NpcContent.available_moves(_fenn(), gs, CanonLog.new())
	assert_true("accept_item(worn_shortsword)" in moves)


func test_a_broke_party_is_asked_for_nothing():
	var moves = NpcContent.available_moves(_fenn(), GameState.new(), CanonLog.new())
	for denom in ["copper", "silver", "gold"]:
		assert_false("accept_item(%s)" % denom in moves, "an empty purse cannot pay a %s" % denom)


func test_accept_item_denomination_gated_on_affordability():
	var gs = GameState.new()
	gs.grant("copper", 347)
	var moves = NpcContent.available_moves(_fenn(), gs, CanonLog.new())
	assert_true("accept_item(copper)" in moves)
	assert_true("accept_item(silver)" in moves)
	assert_false("accept_item(gold)" in moves, "347c cannot pay a gold coin")


func test_a_gold_coin_is_asked_for_once_affordable():
	var gs = GameState.new()
	gs.grant("gold", 1)
	var moves = NpcContent.available_moves(_fenn(), gs, CanonLog.new())
	assert_true("accept_item(gold)" in moves)


func test_currency_gift_is_offered_repeatedly():
	var npc := _fenn()
	npc["capabilities"]["giveable_items"] = ["copper", "amulet"]
	var gs = GameState.new()
	gs.mark_gift_given("copper")
	gs.mark_gift_given("amulet")
	var moves = NpcContent.available_moves(npc, gs, CanonLog.new())
	assert_true("give_item(copper)" in moves, "money is not a one-shot gift")
	assert_false("give_item(amulet)" in moves, "a real item still is")